Botões / ações ( actions) para ajudar no desenvolvimento

Caminho
Base:= @Subset(@DbName;-1);
Server:= @Name([CN];@Subset(@DbName;1));
@Prompt([OkCancelEdit];"Caminho";"Caminho";Server + "\\" + Base)

AtualizaDocSelecionado
@Command([ToolsRefreshSelectedDocs])

Bt Ninja
$campo:=@Prompt([OkCancelList];"Super Mega Button";"Selecione o campo que será alterado:";"";@DocFields);
$perg01:=@Text(@Prompt([YesNo];"Super Mega Button";"O valor do campo " + $campo + " é numérico?"));

@If(
$perg01="1";
@Do(
$valor_num:=@Prompt([OkCancelEdit];"Super Mega Button";"Informe o valor numérico do campo " + $campo +":";"");
@SetField($campo;@TextToNumber($valor_num))
);
@Do(
$perg02:=@Text(@Prompt([YesNo];"Super Mega Button";"O valor do campo " + $campo + " é data (formato: dd/mm/aaaa)?"));
@If(
$perg02="1";
@Do(
$valor_dia:=@Prompt([OkCancelEdit];"Super Mega Button";"Informe o valor do dia (2 dígitos) para o campo " + $campo +":";"");
$valor_mes:=@Prompt([OkCancelEdit];"Super Mega Button";"Informe o valor do mês (2 dígitos) para o campo " + $campo +":";"");
$valor_ano:= @Prompt([OkCancelEdit];"Super Mega Button";"Informe o valor do ano (4 dígitos) para o campo " + $campo +":";"");
$valor_data:=@Date(@TextToNumber($valor_ano);@TextToNumber($valor_mes);@TextToNumber($valor_dia));
@SetField($campo;$valor_data)
);
@Do(
$perg03:=@Text(@Prompt([YesNo];"Super Mega Button";"O campo " + $campo + " é multi-valorado?"));
@If(
$perg03="1";
@Do(
$valor_multi:=@Prompt([OkCancelEdit];"Super Mega Button";"Informe o valor texto para incluir na lista do campo " + $campo +":";"");

$lista:=@Implode(@GetField($campo);",");
@SetField($campo;@Explode($lista+","+@Text($valor_multi);","))
);
@Do(
$valor_texto:=@Prompt([OkCancelEdit];"Super Mega Button";"Informe o valor texto do campo " + $campo +":";"");
@SetField($campo;@Text($valor_texto))
))))))


Bt Ninja 2
REM { v1.2 - if field exists, uses default value and default field type in @Prompt dialogs [Raphael Rodrigues, 2007-08-08]};

unid:= @Text(@DocumentUniqueID);

theField := @Prompt([OkCancelList]; "Change Field"; "Select Field"; ""; "":@DocFields);

currValueTemp:= @If( @IsAvailable(theField); @GetDocField(unid; theField); "errorTemp" );
currValue:= @If( @IsError(currValueTemp); "errorValue"; @If(@Elements(currValueTemp)>1;@Implode(@Text(currValueTemp);";");@Text(currValueTemp)) );
theValue := @Prompt([OkCancelEdit]; "Change Field"; "New Value: use semicolon separator for lists."; currValue);

currType:= @If( @IsNumber(currValueTemp); "Number"; @IsTime(currValueTemp); "Time"; "Text" );
theType := @Prompt([OkCancelList]; "Change Field"; "Data Type"; currType; "Text" : "Time" : "Number" : "Text List" : "Number List" : "Time List");

@If(

theType = "Time";
@SetField(theField; @TextToTime(theValue));

theType = "Number";
@SetField(thefield; @TextToNumber(theValue));

theType = "Text List";
@SetField(theField; @Trim(@Explode(theValue;";")));

theType = "Number List";
@SetField(theField; @TextToNumber(@Explode(@Trim(@ReplaceSubstring(theValue;" ";""));";")));

theType = "Time List";
@SetField(theField; @TextToTime(@Explode(theValue;";")));

@SetField(theField; @Text(theValue))
)